home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64Games / WHEEL-OF-FORTUNE2.SDA / LIST CREATOR (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  5.6 KB  |  171 lines
  1. 1 DIM WO$(50,50),CA$(100),Y(100)
  2. 3 PRINT"[147]":POKE53280,0:POKE53281,0
  3. 5 OPEN15,8,15
  4. 10 GOSUB20000
  5. 15 GOSUB2100
  6. 20 PRINT"DO YOU WANT TO A[146]DD OR E[146]RASE A CATAGORY"
  7. 25 GETA$:IF A$=""THEN 25
  8. 30 IF A$="A" THEN NS=NS+1:GOTO100
  9. 35 IF A$="E" THEN GOSUB6000:PRINT"[147]":GOTO10
  10. 40 GOTO25
  11. 100 PRINT"[147]       ****ADD NEW WORD LISTS****       "
  12. 120 PRINT"NAME WHICH GROUPS THE FIVE CATAGORIES   ";
  13. 125 PRINT"EXAMPLES:STANDARD, STANDARD II,SPORTS   ";
  14. 135 PRINT"ROCK MUSIC...ETC(11 CHARACTER MAXIMUM)"
  15. 150 INPUTNF$(NS):NF$(NS)=NF$(NS)+"           ":NF$(NS)=LEFT$(NF$(NS),11)
  16. 200 Y$="N":IF NS>1 THEN X=X:FORI=1TONS-1:IF NF$(NS)=NF$(I)THEN Y$="Y"
  17. 210 IF NS>1 THEN NEXT
  18. 250 IF Y$="Y"THEN PRINT"***YOU ALREADY HAVE A SET NAMED THAT.***"
  19. 260 IF Y$="Y"THENX=X:FORI=1TO4000:NEXT:GOTO100
  20. 900 PRINT""
  21. 1000 FORI=5*NS-4 TO 5*NS
  22. 1010 PRINT"NAME OF CATAGORY #";I"  (11 LETTER MAX)"
  23. 1012 INPUTCA$(I):IFLEN(CA$(I))>11THENPRINT"SORRY TOO MANY LETTERS TRY AGAIN[145][145]"
  24. 1015 IFLEN(CA$(I))>11THEN 1012
  25. 1020 CA$(I)=CA$(I)+"           ":CA$(I)=LEFT$(CA$(I),11)
  26. 1030 NEXT
  27. 1190 I=1
  28. 1200 FORJ=NS*5-4 TO NS*5
  29. 1300 PRINT"[147]ENTER WORD #";I"FOR CATEGORY "CA$(J)
  30. 1310 PRINT"[158]                                   [146]"SPC(5);" [146]";
  31. 1312 PRINT"                                  [146]";
  32. 1315 PRINT"[158]                                   [146][145][145]"SPC(6);" [146][157]";
  33. 1316 WO$(J,I)="":K=1
  34. 1317 GETA$:IF A$=""THEN 1317
  35. 1318 IF ASC(A$)=95 AND I>1 THEN I=I-1:GOTO 1300
  36. 1320 IF ASC(A$)>64 AND ASC(A$)<91 THEN 1327
  37. 1321 IF A$="."OR A$="-" OR A$="'" OR A$=" "THEN 1327
  38. 1322 IF ASC(A$)=13 THEN 1330
  39. 1323 IF ASC(A$)=20ANDK>1THENPRINT"[146][157]  [157][157] [146][157]";
  40. 1324 IF ASC(A$)=20ANDK>1THEN WO$(J,I)=LEFT$(WO$(J,I),(LEN(WO$(J,I))-1))
  41. 1325 IF ASC(A$)=20ANDK>1THEN A$="":K=K-1:GOTO1317
  42. 1326 GOTO1317
  43. 1327 PRINTA$" [146][157]";:WO$(J,I)=WO$(J,I)+A$:K=K+1:IFK=34THENPRINT"[158] [146]":GOTO1330
  44. 1328 GOTO1317
  45. 1330 K=1:IFWO$(J,I)=""THENPRINT"IS THAT ALL THE WORDS YOU WANT (Y/N)":GOTO1332
  46. 1331 NEXT:GOTO1400
  47. 1332 A$=""
  48. 1335 GETA$:IF A$=""THEN 1335
  49. 1336 IF A$="Y"THEN I=I-1:GOTO1620
  50. 1337 IFA$="N"THENPRINT"THEN YOU MUST RE-ENTER THE LAST SET OF  WORDS.":GOTO1700
  51. 1338 GOTO1335
  52. 1360 IF A$="Y"THEN1620
  53. 1400 I=I+1:GOTO1200
  54. 1620 MIN=I:GOSUB2000:GOSUB2310:GOTO10
  55. 1700 FORX=1TO3000:NEXT:GOTO1200
  56. 2000 REM*CREATE FILES TO STORE FILENAMES****************************************
  57. 2002 PRINT#15,"S:FILES":INPUT#15,A$
  58. 2005 OPEN2,8,2,"FILES,S,W"
  59. 2010 PRINT#2,NS
  60. 2020 FORI=1 TO NS
  61. 2030 PRINT#2,NF$(I)
  62. 2040 FORJ=5*I-4 TO 5*I
  63. 2050 PRINT#2,CA$(J)
  64. 2060 NEXT:NEXT:CLOSE2:RETURN
  65. 2099 REM*READ IF FILELIST EXISTS************************************************
  66. 2100 REM
  67. 2105 OPEN2,8,2,"FILES,S,R"
  68. 2107 INPUT#15,A$:A=VAL(A$):IF A=62THEN CLOSE2:GOSUB4000:RETURN
  69. 2108 IF A>0 THEN GOSUB4100:CLOSE2:GOTO2105
  70. 2109 PRINT"[147]FILES ON DISK IN DISK DRIVE."
  71. 2110 INPUT#2,NS
  72. 2120 FORI=1 TO NS
  73. 2130 INPUT#2,NF$(I)
  74. 2140 FORJ=5*I-4 TO 5*I
  75. 2150 INPUT#2,CA$(J)
  76. 2160 NEXT:GOSUB5000:NEXT:CLOSE2:RETURN
  77. 2199 REM*DETERMINE IF DISK ERROR************************************************
  78. 2200 OPEN15,8,15
  79. 2300 REM********CREATE INDIVIDUAL FILES***************************************
  80. 2310 OPEN2,8,2,NF$(NS)+",S,W"
  81. 2320 FORI=5*NS-4 TO NS*5:PRINT#2,CA$(I):NEXT
  82. 2330 PRINT#2,MIN
  83. 2335 XY=1
  84. 2340 PRINT#2,XY
  85. 2350 CLOSE2
  86. 2399 REM*****CREATE INDIVIDUAL FILES***
  87. 2400 FORI=1 TO 5
  88. 2405 CD$=STR$(5*NS-5+I):CD=VAL(CD$)
  89. 2410 OPEN2,8,2,CD$+",S,W"
  90. 2420 FORK=1TO MIN
  91. 2430 PRINT#2,WO$(CD,K)
  92. 2440 NEXT:CLOSE2:NEXT:RETURN
  93. 4000 REM******SAY THAT NO FILES EXIST**
  94. 4010 PRINT"[147]THERE ARE NO FILES ON THIS DISK SO FAR."
  95. 4020 FORI=1TO1000:NEXT:RETURN
  96. 4100 REM****SAY TO TURN DRIVE ON AND OFF****
  97. 4110 PRINT"[147]DISK ERROR #";A
  98. 4120 PRINT"PLEASE TURN DRIVE OFF"
  99. 4130 PRINT"THEN ON TO TRY AGAIN."
  100. 4135 PRINT"PRESS ANY KEY WHEN READY."
  101. 4136 GETA$:IF A$=""THEN 4136
  102. 4140 RETURN
  103. 5000 REM*****SHOW FILES AND CATAGORIES
  104. 5030 PRINTI"[157])"NF$(I)"[146]"CA$(J-5)""CA$(J-4)""CA$(J-3)""CA$(J-2);
  105. 5040 PRINT""CA$(J-1)"":RETURN
  106. 6000 REM*ERASE GROUP CATAORY SUBROUTINE
  107. 6010 PRINT"ERASE WHICH SET OF CATAGORIES":PRINT"(EXAMPLE 1[146])";
  108. 6020 GETA$:IF A$=""THEN 6020
  109. 6030 A=VAL(A$):IF A<1 OR A>NS THEN 6020
  110. 6040 PRINT A
  111. 6050 PRINT"ERASING ALL ";NF$(A);"[146] CATAGORIES"
  112. 6150 FORI=A*5-4 TO A*5
  113. 6160 A$=STR$(I)
  114. 6170 PRINT#15,"S:"+A$
  115. 6180 NEXT
  116. 6200 REM
  117. 6205 IF A=NS THEN 6280
  118. 6210 FORI=A TO NS-1
  119. 6220 NF$(A)=NF$(A+1)
  120. 6230 FORJ=I*5-4 TO I*5
  121. 6240 CA$(J)=CA$(J+5)
  122. 6245 A$=STR$(J):B$=STR$(J+5)
  123. 6250 PRINT#15,"R:"+A$+"="+B$
  124. 6260 NEXT
  125. 6270 NEXT
  126. 6280 NS=NS-1
  127. 6290 GOSUB2000
  128. 6300 RETURN
  129. 19999 REM*****INSTRUCTION SHEET*******
  130. 20000 PRINT"[147][158]*****WHEEL OF FORTUNE WORD CREATOR.*****";
  131. 20010 PRINT"[158]*TO USE THIS PROGRAM, YOU MUST FIRST   [158]*";
  132. 20020 PRINT"[158]*DECIDE WHETHER YOU WANT TO CREATE A   [158]*";
  133. 20030 PRINT"[158]*WORD LIST OR ERASE ONE. IF YOU WANT TO[158]*";
  134. 20040 PRINT"[158]*CREATE A WORD LIST, JUST ENTER A NAME [158]*";
  135. 20050 PRINT"[158]*THAT DESCRIBES WHAT LINKS THE SUBJECTS[158]*";
  136. 20060 PRINT"[158]*TOGETHER(IT CAN BE JUST ABOUT ANYTHING[158]*";
  137. 20070 PRINT"[158]*YOU WANT PROVIDED YOU DON'T HAVE      [158]*";
  138. 20080 PRINT"[158]*ANOTHER SET OF FILES ON THAT DISK WITH[158]*";
  139. 20090 PRINT"[158]*THAT NAME ALREADY). NEXT ENTER THE    [158]*";
  140. 20100 PRINT"[158]*NAMES OF EACH OF THE FIVE CATAGORIES, [158]*";
  141. 20110 PRINT"[158]*THEN START ENTERING THE ACTUAL WORDS, [158]*";
  142. 20120 PRINT"[158]*ALTERNATING THE FIVE CATAGORIES. YOU  [158]*";
  143. 20130 PRINT"[158]*WILL SEE WHICH CATAGORY YOU ARE       [158]*";
  144. 20140 PRINT"[158]*SUPPOSED TO BE ENTERING.              [158]*";:GOSUB25000
  145. 20150 PRINT"[147][158]***EDITING TIPS:[146]************************";
  146. 20160 PRINT"[158]*WHEN TYPING IN THE WORDS, YOU MAY USE [158]*";
  147. 20167 PRINT"[158]*LETTERS, COMMAS, PERIODS, HYPHENS, AND[158]*";
  148. 20170 PRINT"[158]*SPACES. EACH PUZZLE MAY BE 33 CHAR.   [158]*";
  149. 20180 PRINT"[158]*LONG, BUT IF YOUR PUZZLE IS LESS THAN [158]*";
  150. 20190 PRINT"[158]*33 CHAR. YOU CAN PRESS RETURN WHEN YOU[158]*";
  151. 20200 PRINT"[158]*ARE DONE WITH YOUR PUZZLE. IF YOU MAKE[158]*";
  152. 20210 PRINT"[158]*A MISTAKE, YOU MAY GO BACK AND RETYPE [158]*";
  153. 20220 PRINT"[158]*IN THE LAST SET OF WORDS BY PRESSING  [158]*";
  154. 20230 PRINT"[158]*THE _[146] KEY. NOTE:[146] YOU MUST RETYPE IN   [158]*";
  155. 20240 PRINT"[158]*ALL THE WORDS FROM THAT NUMBER SET.   [158]*";
  156. 20250 PRINT"[158]*WHEN YOU ARE THROUGH ENTERING ALL YOUR[158]*";
  157. 20260 PRINT"[158]*WORDS PRESS RETURN AS THE FIRST CHAR. [158]*";
  158. 20270 PRINT"[158]*AND ANSWER Y WHEN IT ASKS IF YOU ARE  [158]*";
  159. 20280 PRINT"[158]*THROUGH. YOUR WORDLIST WILL THEN BE   [158]*";
  160. 20290 PRINT"[158]*SAVED ONTO DISK.                      [158]*";
  161. 20300 PRINT"[158]*                                      [158]*";
  162. 20310 PRINT"[158]*                                      [158]*";
  163. 20320 PRINT"[158]*                                      [158]*";
  164. 20330 PRINT"[158]*                                      [158]*";
  165. 20340 PRINT"[158]*                                      [158]*";
  166. 20350 PRINT"[158]*                                      [158]*";:GOSUB25000:RETURN
  167. 25000 PRINT"[158]****************************************";
  168. 25010 PRINT"       [150]PRESS ANY KEY TO CONTINUE.[158]"
  169. 25020 GETA$:IF A$=""THEN 25020
  170. 25030 RETURN
  171.